 ; Multiple text Height Change - also works on fixed height text and attdefs.
 ; Copyright 1990, 2001 by Rocket Software
 ; A function Autodesk forgot.
 (defun C:HT ( / ss cc nn num lll lln zz tt)
  (setvar "cmdecho" 0)
  (prompt "Select text to change:")
  (if (setq ss (ssget '((-4 . "<or") (0 . "text") (0 . "mtext") (0 . "attdef")
                        (-4 . "or>"))))
      (progn
           (setq tt (strcat "<" (rtos (cdr (assoc 40 (entget (ssname ss 0)))))
                            "> New height or <Return> to select: "))
           (if (null (setq cc (getreal tt)))
               (progn
                    (setq nn (entget (car (entsel "Text of desired height: "))))
                    (setq typ (cdr (assoc 0 nn)))
                    (if (member typ '("TEXT" "ATTDEF" "MTEXT"))
                        (setq cc (cdr (assoc 40 nn))))))
           (setq num 0)
           (while (and cc (setq lll (ssname ss num)))
                  (setq num (1+ num))
                  (setq lln (entget lll))
                  (setq zz (cdr (assoc 40 lln)))
                  (entmod (subst (cons 40 cc) (cons 40 zz) lln)))
           (prompt (strcat "Lines changed: " (itoa num)))))
 (princ))