 ; Lash - toggle polyline linetype generation: overall/vertex-vertex.
 ; Copyright 1994 by Rocket Software
 ; Overkill, you say?
 (DEFUN C:LASH (/ enampt entt typ cont nuc)
  (setq enampt (entsel "Polyline to lash: "))
  (if (and enampt 
           (setq typ (cdr (assoc 0 (setq entt (entget (car enampt))))))
           (or (= typ "POLYLINE") (= typ "LWPOLYLINE")))
      (progn
           (setq cont (assoc 70 entt))
           (if (= (logand (cdr cont) 128) 128)
               (setq nuc (cons 70 (boole 6 (cdr cont) 128)))
               (setq nuc (cons 70 (logior (cdr cont) 128))))
           (entmod (subst nuc cont entt))))
 (princ))