 ; Lsc - change entity linetype scales.
 ; Also contains Lsn - set linetype scales to bylayer (= not stored in entity.)
 ; Copyright 2004, 2005 by Rocket Software Ltd.
 ;
 (DEFUN C:LSC (/ ss desp num enam entt)
  (if (setq ss (ssget))
      (progn
           (if (not (member (type desult) '(REAL INT))) (setq desult 1.0))
           (setq desp (getreal (strcat "Desired entity ltscale <"
                                       (rtos desult 2 2)
                                       ">: ")))
           (if desp (setq desult desp))
           (setq num 0)
           (while (setq enam (ssname ss num))
                  (setq num (1+ num))
                  (setq entt (entget enam))
                  (cond ((setq sub (assoc 48 entt))
                         (entmod (subst (cons 48 desult) sub entt)))
                        ((/= desult 1)
                         (entmod (append entt (list (cons 48 desult)))))))))
 (princ))

 (DEFUN C:LSN (/ ss)
  (if (setq ss (ssget))
      (command ".change" ss "" "p" "s" 1 ""))
 (princ))

(princ)