 ; DDD - swap attribute values: "" to "..." & vice versa.
 ; Copyright 1994, 2003, 2004 by Rocket Software Ltd.
 ; Also contains DDDD - kill all "..." values, in case you screw up.
 ; One of the routines Captain Nemo used to design the Nautilus.

 (DEFUN C:DDDD (/ ss num enam esav entt)
  (setq ss (ssget (list (cons 0 "insert"))))
  (setq num 0)
  (while (setq esav (setq enam (ssname ss num)))
         (setq num (1+ num))
         (if (= 1 (cdr (assoc 66 (entget enam))))
             (while (/= "SEQEND" (cdr (assoc 0 (setq entt (entget
                                              (setq enam (entnext enam)))))))
                    (if (= (cdr (assoc 1 entt)) "...")
                        (entmod (subst (cons 1 "") (assoc 1 entt) entt)))))
         (entupd esav))
 (princ))

 (DEFUN DDD (enam / esav entt)
  (setq esav enam)
  (while (/= (cdr (assoc 0 (setq entt (entget (setq enam (entnext enam))))))
                                                                      "SEQEND")
         (cond ((or (= (cdr (assoc 1 entt)) "")
                    (= (cdr (assoc 1 entt)) " "))
                (entmod (subst (cons 1 "...") (assoc 1 entt) entt)))
               ((= (cdr (assoc 1 entt)) "...")
                (entmod (subst (cons 1 "") (assoc 1 entt) entt)))))
  (entupd esav)
 (princ))

 (DEFUN C:DDD (/ ss enam)
  (setq ss (ssget (list (cons 0 "insert"))))
  (setq num 0)
  (while (setq enam (ssname ss num))
         (setq num (1+ num))
         (if (= 1 (cdr (assoc 66 (entget enam))))
             (ddd enam)))
 (princ))